大家好，我是LinuxZn。

Hello系列，汇总短而实用的内容。

上一篇文章中我们分享了关于make与Makefile的知识：Hello系列 | Makefile必备基础知识梳理。make工具有很多种：gnu make、QT的qmake、微软的MS nmake等。不同的make工具遵循不同的规范，如果我们的程序想要运行在不同的平台上，就需要根据不同地平台的make工具规范编写对应的Makefile文件。显然，这很不方便。

CMake就是一个可以解决上面这个问题的工具。

什么是cmake？

CMake 是一个跨平台的安装(编译)工具。CMakeList.txt是一个与平台无关的、用于定制编译流程的文件。CMake 靠的是 CMakeLists.txt 文件来生成Makefile文件。

CMakeLists.txt文件的编写也需要遵循一些语法规则，CMakeLists.txt文件的语法与shell脚本的语法很相似，shell编程知识可见往期文章：Hello系列 | shell编程必备简明基础知识。

下面简单了解CMakeLists.txt简单的规则及一些示例。

cmake语法知识

1、直译模式

直译模式简单解释就是不生成Makefile的模式。这很方便我们验证一些CMakeLists.txt的语法及验证一些数学运算等。

下面通过简单实例区分直译模式与非直译模式的区别。

直译模式：

输入 -P参数 指定CMakeLists.txt脚本以直译模式解析。其中，message是CMakeLists.txt中用于输出信息的命令。以直译模式解析就不会生成Makefile文件，并且终端输出的信息就是我们CMakeLists.txt指定输出的内容。

非直译模式：

可见，以非直译模式解析则会生成Makefile文件，并且终端多输出了一些核查编译器相关的信息。

2、定义变量

CMakeLists.txt中只有字串和字串数组两种变量。定义变量通过 set命令 来定义，使用变量时在外面加上 ${} 符号即可。如：

# 定义变量
set(name "LinuxZn")

# 使用变量
message("My name is ${name}!")

① 注释使用符号 #。

② 命令不区分大小写，即set也可以替换为SET。

3、数学运算

# EXPR 是一款表达式计算工具
# math 是用于数学运算的命令

# 设置变量a、b的值
set(a "1")
set(b "2")

# 加
math(EXPR res "${a} + ${b}")
message("a + b : ${res}")

# 减
math(EXPR res "${a} - ${b}")
message("a - b : ${res}")

# 乘
math(EXPR res "${a} * ${b}")
message("a * b : ${res}")

# 除
math(EXPR res "${a} / ${b}")
message("a / b : ${res}")

# 取余
math(EXPR res "${a} % ${b}")
message("a % b : ${res}")

4、从命令行给变量赋值

# EXPR 是一款表达式计算工具
# math 是用于数学运算的命令

# 加
math(EXPR res "${a} + ${b}")
message("a + b : ${res}")

# 减
math(EXPR res "${a} - ${b}")
message("a - b : ${res}")

# 乘
math(EXPR res "${a} * ${b}")
message("a * b : ${res}")

# 除
math(EXPR res "${a} / ${b}")
message("a / b : ${res}")

# 取余
math(EXPR res "${a} % ${b}")
message("a % b : ${res}")

-D后面跟着变量及赋值。

我们经常会在命令行配置工程为debug模式还是release模式，如：

cmake -DCMAKE_BUILD_TYPE=Debug

CMAKE_BUILD_TYPE是cmake中的一个内置变量，用于指定构建类型。

5、流程控制

（1）if

set(ARCH "x86")
if(ARCH MATCHES "x86")
    message("ARCH is x86")
else()
    message("ARCH is arm")
endif()

（2）while

set(a "1")
while(${a} LESS "5")
    message("${a}")          
    math(EXPR a "${a} + 1")
endwhile()

（3）foreach

message("for 1 =========")
foreach(i RANGE 1 5)
    message("${i}")
endforeach()

message("for 2 =========")
foreach(i 1 5 6 7 9 10)
    message("${i}")
endforeach()

message("for 3 =========")
foreach(str Linux C Cpp Python Shell)
    message("${str}")
endforeach()

6、自定义宏与函数

（1）宏

# 定义名为printf的宏 
macro(printf str)
    message(${str})
endmacro()

# 使用
printf("hello macro")

（2）函数

# 定义名为printf的函数 
function(printf str)
    message(${str})
endfunction()

# 使用
printf("hello function")

（3）宏与函数的区别

函数中的变量是局部的，宏中的变量是全局的，宏中的变量在外面也可以被访问到。

# 定义名为func_printf的函数 
function(func_printf str)
    message(${str})
    set(func_var "1111111111")
endfunction()

# 定义名为macro_printf的宏 
macro(macro_printf str)
    message(${str})
    set(macro_var "222222222")
endmacro()

# 使用
func_printf("hello function")
message("func_var = ${func_var}")
macro_printf("hello macro")
message("macro_var = ${macro_var}")

7、查看cmake命令说明

上面列举的语法知识中，我们并未介绍所用命令的格式及使用方式。各命令详细的解释可以通过如下方式查看。

（1）查看所有cmake命令

cmake --help-command-list

（2）查看具体某个命令说明

比如，查看message命令说明：

cmake --help-command message

cmake与构建

上一节分享了cmake的一些基本语法知识。这一节我们一起来看一下cmake与构建相关的内容。

1、几个常用命令

下面列出几个常用的命令，在我们下面的例子中会用到。

（1）cmake_minimum_required

命令格式：

cmake_minimum_required(VERSION major.minor[.patch[.tweak]]
                        [FATAL_ERROR])

用于指定需要的 CMake 的最低版本。

使用示例：

cmake_minimum_required (VERSION 3.10)

（2）project

命令格式：

project(<PROJECT-NAME> [LANGUAGES] [<language-name>...])

用于指定项目的名称。

使用示例：

project (hello)

（3）add_executable

命令格式：

add_executable(<name> [WIN32] [MACOSX_BUNDLE]
                [EXCLUDE_FROM_ALL]
                source1 [source2 ...])

用于指定从一组源文件 source1 … 编译出一个可执行文件且命名为 name。

使用示例：

add_executable(hello main.c)

（4）aux_source_directory

命令格式：

aux_source_directory(<dir> <variable>)

用于将 dir 目录下的所有源文件的名字保存在变量 variable 中。

使用示例：

aux_source_directory(. DIR_SRCS)

（5）add_subdirectory

命令格式：

add_subdirectory(source_dir [binary_dir]
                  [EXCLUDE_FROM_ALL])

用于添加一个需要进行构建的子目录。

使用示例：

add_subdirectory(Lib)

（6）add_library

命令格式：

add_library(<name> INTERFACE [IMPORTED [GLOBAL]])

用于指定从一组源文件中编译出一个库文件且命名为name。

使用示例：

add_library(Lib ${DIR_SRCS})

（7）target_link_libraries

命令格式：

target_link_libraries(<target> ... <item>... ...)

用于指定 target 需要链接 item1 item2 …。

使用示例：

target_link_libraries(hello Lib)

（8）include_directories

命令格式：

include_directories([AFTER|BEFORE] [SYSTEM] dir1 [dir2 ...])

用于添加头文件路径。

使用示例：

include_directories(include)

2、常用内置变量

（1）PROJECT_SOURCE_DIR

目前正在处理中的专案最上层目录，即内含 project() 指令的 CMakeLists 所在资料夹。

（2）CMAKE_BUILD_TYPE

控制构建类型，可选值为：

• None: 编译器默认值
• Debug: 产生除错信息
• Release: 进行最佳化
• RelWithDebInfo: 进行最佳化，但仍然会启用 DEBUG flag
• MinSizeRel: 进行程式码最小化

（3）CMAKE_C_FLAGS

C编译器的编译选项。

（4）CMAKE_CXX_FLAGS

C++编译器的编译选项。

3、实例

（1）基础实例

main.c：

#include <stdio.h>

int main(void)
{
    printf("hello cmake\n");
    return 0;
}

CMakeLists.txt：

cmake_minimum_required (VERSION 3.10)
project (hello)
add_executable(hello main.c)

（2）多个文件、多个文件夹

上一个demo只有一个源文件，对应的CMakeLists.txt比较简单。下面看看有多个文件夹及文件的工程。

基于上面的demo，修改工程如：

main.c：

#include "hello.h"

int main(void)
{
    print_hello();
    return 0;
}

CMakeLists.txt：

cmake_minimum_required (VERSION 3.10)
project (hello)

# 添加头文件路径
include_directories(include)

# 查找src目录下的所有源文件并将名称保存到 SRC_DIR_SRCS 变量中
aux_source_directory(src SRC_DIR_SRCS)

# 查找当前目录下的所有源文件并将名称保存到 CUR_DIR_SRCS 变量中
aux_source_directory(. CUR_DIR_SRCS)

# 从SRC_DIR_SRCS与CUR_DIR_SRCS中编译出可执行文件hello
add_executable(hello 
              ${SRC_DIR_SRCS}
              ${CUR_DIR_SRCS}
              )

编译、运行：

cd build
cmake ..
make
./hello

（3）编译静态库

基于demo2，我们把src文件夹下的源文件编译成静态库，再由main.c调用。工程目录基本不变，需要在src下新增一个CMakeLists.txt文件，其内容如：

# 查找当前目录下的所有源文件并将名称保存到 DIR_LIB_SRCS 变量
aux_source_directory(. DIR_LIB_SRCS)

# 生成链接库
add_library (print_hello ${DIR_LIB_SRCS})

根目录下的CMakeLists.txt修改为：

cmake_minimum_required (VERSION 3.10)
project (hello)

# 添加头文件路径
include_directories(include)

# 查找当前目录下的所有源文件并将名称保存到 CUR_DIR_SRCS 变量中
aux_source_directory(. CUR_DIR_SRCS)

# 添加 src 子目录
add_subdirectory(src)

# 从CUR_DIR_SRCS中编译出可执行文件hello
add_executable(hello 
              ${CUR_DIR_SRCS}
              )

# 添加链接库
target_link_libraries(hello print_hello)

编译、运行：

cd build
cmake ..
make
./hello

（4）编译动态库

编译动态库的方式与编译动态库的方式差不多。基于上面的demo3，只需修改src文件夹下的CMakeLists.txt为：

# 查找当前目录下的所有源文件并将名称保存到 DIR_LIB_SRCS 变量
aux_source_directory(. DIR_LIB_SRCS)

# 生成动态库
add_library (print_hello SHARED ${DIR_LIB_SRCS})

编译、运行：

cd build
cmake ..
make
./hello

4、支持gdb调试

上面工程中根目录加上如下命令可支持gdb调试：

set(CMAKE_BUILD_TYPE "Debug")
set(CMAKE_CXX_FLAGS_DEBUG "$ENV{CXXFLAGS} -O0 -Wall -g -ggdb")
set(CMAKE_CXX_FLAGS_RELEASE "$ENV{CXXFLAGS} -O0 -Wall")

以上就是本次的分享。如果觉得文章有用，欢迎收藏、转发！

相关资料：

https://www.hahack.com/codes/cmake/

https://preshing.com/20170522/learn-cmakes-scripting-language-in-15-minutes/

https://cmake.org/