当前位置：网站首页 > IT知识 > 正文

如何编写基于窗口的脚本解释程序_如何编写基于窗口的脚本解释程序

liuian 2025-08-31 03:59 19 浏览

今天一时兴起，利用已有控件写了一个基于窗口，语法高亮显示的 Lysee 脚本解释程序，借此文章分享一下具体的开发的过程。

一、简要说明

这个程序长这个样子，名字暂定为 laoke 唠嗑的意思，下面是这个程序的第一张截图，后续会把这个程序的源代码上传到 gitee 上（
https://gitee.com/lysee/lysee.git）。

相比下面这种长期使用的 console 版本，由于语法加亮，感觉舒爽多了。

二、开发过程

1.选择适宜的语法加亮编辑器

这里选择使用 TLyCodeMemo，这个编辑器使用在 lwrite 程序中，是 Lysee 套件的一部分。当然也可以选择使用 Lazarus 自带的 TSynEdit，基本原理是一样的。

2.建立规则

为编辑器建立终端录入模式。
只有在编辑器最后一行时才允许修改、剪切、粘贴。
增加 write 函数，让解释程序可以向编辑器写入文本，像 stream 一样追加到文档尾部。
记录 write 函数写入后，最后一行的位置，在这个位置之前不允许修改任何内容。
修改编辑器对回车换行的处理，在最后一行回车时将回车位置前的实际输入内容回传给解释程序执行。解释程序执行完毕后，再向编辑器写入输入提示符。
如此循环往复，完成交互过程。

3.编写代码

3.1 为编辑器增加中断模式和 write 函数，记录写入情况：

procedure TLyCodeMemo.Write(const S: string);
var
W: WideString;
begin
if not (msTerminal in FState) then Exit; // 新增的 msTerminal 状态
{$IFDEF UNICODE}
W := S;
{$ELSE}
W := UTF8Decode(S);
{$ENDIF}
FSelection.UnSelect;
FCaret.MoveToTail(FLines.Last);
FSelection.SetText(W);
FCaret.MoveToTail(FLines.Last);
FWriteCount := Length(FLines.Last.Text);
end;

3.2 检测选择内容和位置是否只读，只读时禁止录入。

function TLySelection.GetReadonly: boolean;
var
L, M: TLyLine;
begin
Result := FMemo.Readonly or (FMemo.Terminal and FSelectAll);
if not Result and FMemo.Terminal then
begin
L := FMemo.Lines.Last;
if Selected then
begin
M := FMemo.FLines[FHead.ItemX];
Result := (M <> L) or (FHead.TextX < FMemo.FWriteCount);
end
else
begin
M := FMemo.FCaret.GetItem;
Result := (M <> L) or (FMemo.FCaret.FPos.TextX < FMemo.FWriteCount);
end;
end;
end;

3.3 接管编辑器回车换行处理

if (Key = #10) or (Key = #13) then
begin
H := (msTerminal in FState) and (FCaret.Item = FLines.Last) and Assigned(FOnInput);
if H then
begin
N := FWriteCount;
L := FLines.Last;
end;
FSelection.SetText(sLineBreak);
if H then
begin
if N > 0 then
C := Copy(L.FText, N + 1, Length(L.FText)) else
C := L.FText;
L := FLines.Last;
W := L.FText;
L.SetText('');
FWriteCount := 0;
FOnInput(Self, WideToStr(C));
L := FLines.Last;
L.SetText(L.FText + W);
FCaret.MoveDocumentEnd;
end;
end

编辑器通过 FOnInput 回调函数向解释程序传送代码。

3.4 解释程序执行代码

procedure TLaokeForm.OnInput(Sender: TObject; const S: string);
function match_head(const S: string; const IDs: array of string): boolean;
var
I: integer;
begin
Result := false;
for I := 0 to Length(IDs) - 1 do
if LyMatchID(IDs[I], Copy(S, 1, Length(IDs[I]))) then
begin
Result := true;
Exit;
end;
end;
function match_fp(const S: string): boolean;
begin
Result := match_head(S, ['function', 'procedure', 'def'])
end;
procedure do_execute(const code: string);
var
V: PLyValue;
N: int64;
begin
try
if code <> '' then
begin
N := FEngine.WriteCount;
if FEngine.Execute(code) then
begin
if N <> FEngine.WriteCount then
if not CharInSet(FEngine.LastWritenChar, [#10, #13]) then
FEngine.Writeln;
V := FEngine.MainThread.Result;
if V^.v_type <> my_nil then
begin
Writeln('--> ' + LyFormatValue(V));
LySetNil(V);
end;
end;
end;
finally
FScript := '';
end;
end;
var
T: string;
L: TLyLine;
begin
if FWaitForInput then
begin
FScript := '';
FInputText := S;
FWaitForInput := false;
Exit;
end;
T := TrimRight(S);
if LyMatchID(Copy(T, 1, 3), ['>>>', ' >']) then
T := Copy(T, 5, Length(T));
if T = '' then do_execute(FScript) else
begin
if LyMatchID('quit', T) then Close else
if FScript <> '' then
FScript := FScript + sLineBreak + T else
if T <> '' then
if (T[Length(T)] <> ';') or match_fp(Trim(T)) then
FScript := T else
do_execute(T);
end;
FInput.UnSelect;
L := FInput.Lines.Last;
if Trim(L.Text) = '' then
begin
if FScript = '' then
L.Text := '>>> ' else
L.Text := ' > ';
end
else
begin
T := WideToStr(L.Text);
if not LyMatchID(T, ['>>> ', ' > ']) then
if FScript = '' then
FInput.Lines.Add('>>> ') else
FInput.Lines.Add(' > ');
end;
FInput.Write('');
end;

3.5 将执行程序 readln 过程委托给编辑器完成

在程序中增加以下状态变量，用于等级输入状态和输入结果

FWaitForInput: boolean;
FInputText: string;

建立 OnReadln 回调函数，在执行程序和编辑器中间建立起联系：

FEngine := TLysee.Create(Self);
FEngine.OnWrite := @OnWrite;
FEngine.OnError := @OnError;
FEngine.OnReadln := @OnReadln;
end;

procedure TLaokeForm.OnReadln(Sender: TObject; var S: string);
begin
FWaitForInput := true;
FInputText := '';
while FWaitForInput do
begin
Application.ProcessMessages;
Sleep(1);
end;
S := FInputText;
end;

当编辑器调用 FOnInput 回调函数时完成输入：

procedure TLaokeForm.OnInput(Sender: TObject; const S: string);
begin
if FWaitForInput then
begin
FScript := '';
FInputText := S;
FWaitForInput := false;
Exit;
end;
.................
end;
end;

大概就是这个过程，不是很复杂，使用其他语法高亮控件应该也能同样原理实现。

开始觉得很难，想着试试算了，没想到真上手一天就全部搞定了。

希望对伙计们能有一些帮助。

说明：Lysee 是本人因以往工作经历和个人爱好开发并维护的一个脚本编程语言，延用 MODIFIED BSD 许可协议，大家可以自由下载使用，但要自行承担风险。Lysee 使用树形结构解析并执行代码，所以执行速度一般，但优势是可以根据需要做语法扩展，扩展方法也很简单，特别适合嵌入 Lysee 实现特定功能地场合。

ofstream 写入文件追加