本文将介绍如何使用Arduino读取RC接收机的PWM数据

支持ESP系列与Atmega系列等使用Arduino框架的MCU

当我们手里拥有一个Arduino设备例如（Arduino Nano、Uno或者ESP8266系列）任何可以使用Arduino进行开发的开发板，我们想让它接收到航模遥控器数据的时候该怎么办呢？本文将介绍如何使用硬件连接与软件编程教您学习它的实现步骤。

硬件准备

1. 一台航模遥控器+接收器

2. 使用Arduino Nano开发板
3. 
   

硬件连接

将Arduino Nano的引脚 D8~D11 接到接收机的1~4通道，接收机上的电源正极和负极连接到Arduino上的GND 和 +5V即可。可见下图我的连接方式。

软件编程

这里我们将使用Vscode平台PlatformIO框架环境进行编写程序。

原理

接收机与arduino通讯将通过pwm的形式与我们的mcu进行数据通信，一般来说此类遥控器的pwm范围最低和最高在 1000 ~ 1500 ~ 2000之间。

例如油门摇杆推在中间为1500，油门放到最低则是1000，油门推到最高为2000。

我们可以采用外部中断来检测引脚的高低电平的变化的持续时间可以计算出pwm值。

由于大部分的arduino有两个外部中断，分别在digital 2和digital 3引脚，中断可由电平的改变触发。

明显这个不能适合我们的使用。

使用引脚电平变化中断 Pin Change Interrupts

这个方法有两种方式第一种不用第三方库 实现起来比较麻烦需要自己写原生的寄存器控制代码

#define LED A3;
byte state = HIGH;
 
void setup() {
  // put your setup code here, to run once:
  Serial.begin(115200);
 
  PCICR |= (1 << PCIE0);                                                    //Set PCIE0 to enable PCMSK0 scan.
  PCMSK0 |= (1 << PCINT0);                                                  //Set PCINT0 (digital input 8) to trigger an interrupt on state change.
  PCMSK0 |= (1 << PCINT1);                                                  //Set PCINT1 (digital input 9)to trigger an interrupt on state change.
  PCMSK0 |= (1 << PCINT2);                                                  //Set PCINT2 (digital input 10)to trigger an interrupt on state change.
  PCMSK0 |= (1 << PCINT3);    
}
 
void loop() {
  // put your main code here, to run repeatedly:
     digitalWrite(A3,state);
}
 
ISR(PCINT0_vect){
  Serial.print("触发中断\t");
  Serial.print(micros());
  Serial.print("\t");
  Serial.println(SPDR,BIN);
  state = ~state;
}

CIE0 代表的是D8 ~ D13的引脚变化，配合 ISR(PCINT0_vect)；
这个解释和使用比较麻烦感兴趣可以看下这篇文章： http://gammon.com.au/interrupts

EnableInterrupt库

我们主要介绍第二种方式采用第三方库：EnableInterrupt

/*
 * @Description:
 * @Author: chenzedeng
 * @Date: 2022-10-27 19:14:34
 * @LastEditTime: 2022-11-05 13:27:13
 */
#define EI_ARDUINO_INTERRUPTED_PIN
#include <EnableInterrupt.h>
 
byte receiver_pins[4] = {8, 9, 10, 11};
volatile int receiver_input[4];
unsigned long timer_1, timer_2, timer_3, timer_4;
 
void pwmReceive();
 
void setup() {
    Serial.begin(115200);
 
    for (int i = 0; i < 4; i++) {
        pinMode(receiver_pins[i], INPUT_PULLUP);
        enableInterrupt(receiver_pins[i], pwmReceive, CHANGE);
    }
    //开启中断
    sei();
}
 
void loop() {
    delay(500);
    Serial.print("---PWM---\n");
    for (int i = 0; i < 4; i++) {
        Serial.print(receiver_input[i]);
        Serial.print("\t");
    }
    Serial.print("---END---\n");
}
 
/**
 * 中断函数
 */
void pwmReceive() {
    //获取当前的PIN触发的引脚
    int currPin = arduinoInterruptedPin;
    //获取当前的微秒
    unsigned long currTime = micros();
 
    //拿到的是当前的引脚的高低电平。 0是从高到低电平，>0 代表是从低到高电平
    int pinLevel = arduinoPinState;
 
    if (currPin == 8 && pinLevel > 0) {
        //为高电平
        timer_1 = currTime;
    } else if (currPin == 8 && pinLevel == 0) {
        //低电平
        receiver_input[0] = currTime - timer_1;
    }
 
    if (currPin == 9 && pinLevel > 0) {
        //为高电平
        timer_2 = currTime;
    } else if (currPin == 9 && pinLevel == 0) {
        //低电平
        receiver_input[1] = currTime - timer_2;
    }
 
    if (currPin == 10 && pinLevel > 0) {
        //为高电平
        timer_3 = currTime;
    } else if (currPin == 10 && pinLevel == 0) {
        //低电平
        receiver_input[2] = currTime - timer_3;
    }
 
    if (currPin == 11 && pinLevel > 0) {
        //为高电平
        timer_4 = currTime;
    } else if (currPin == 11 && pinLevel == 0) {
        //低电平
        receiver_input[3] = currTime - timer_4;
    }
}

将上面的代码烧录到你的arduino中，然后航模遥控器和接收机进行配对，在之后你遥控摇杆就可以发现控制台上的打印数字发生了变化。

注意如果您使用了软串口SoftwareSerial 可能会导致一些不兼容的问题，因为此库实现了ISR( )的方法，请在实际项目中调试做调整。